Files

257 lines
11 KiB
OpenSCAD
Raw Permalink Blame History

This file contains ambiguous Unicode characters
This file contains Unicode characters that might be confused with other characters. If you think that this is intentional, you can safely ignore this warning. Use the Escape button to reveal them.
// Krabička na dutinový filtr 868 MHz (hamparts; 130 x 58 x 40 mm i s konektory, 380 g, SMA female)
// na stožár. Při pohledu zepředu je profil lichoběžník (dno užší než strop),
// takže boční stěny jsou zkosené a dívají se dolů. Vývody vedou kolmo na ně,
// tedy šikmo dolů, a kabel pod krabičkou udělá odkapovou smyčku sám.
// Víko je vpředu na svislé ploše, s těsněním v drážce a šrouby vně těsnění.
// Kabel ven průchodkou PG11 (projde jí SMA konektor, viz gland_hole). Tisk: MK4S, PETG.
// Těsnění víka: silikon vytvrzený v drážce (TPU díl `gasket` je jen volitelný).
//
// Montáž třemi stahovacími pásky (UV černé nebo nerez, do 9 mm) na svislou tyč
// libovolného průřezu. Tunely jsou zapuštěné v zádech, záda zůstávají rovná a celá.
// Dno je trychtýř do odtokové dírky, takže kondenzát vyteče.
//
// Tisk bez supportu ZÁDY DOLŮ: sloupky rostou z podložky, pod přírubou je náběh 45°,
// vstupy tunelů šikmo 45°. Díry pro vývodky jsou kulaté (12,6 mm vodorovně
// většinou projde i bez supportu, jinak tree support jen tam); `gland_teardrop` = slza.
// Šrouby: víko 14x M3x8 DIN 912 A2 do zatavených vložek M3x5x5, filtr 4x M3x10
// s podložkou (uši filtru 4,1 mm) do stejných vložek ve sloupcích.
//
// Osy: X = šířka, Z = nahoru, Y = hloubka (čelo/víko v y=0, záda na stožár v y=-depth).
// Díly: part = "body" | "lid" | "gasket" | "assembly" | "open"
//
// Rozměry filtru jsou z fotek s metrem a z obkreslení podstavy (17. 10. 2026), ne
// posuvkou: tělo ~104 x 58 (výška 45 i se šrouby a rezervou), SMA na obou čelech, mimo střed (~37 mm od jedné dlouhé
// hrany), 4 díry 4 mm v rozích 95 x 51 (změřeno), osa SMA 18 mm nad podstavou. Filtr je symetrický, IN/OUT je jedno;
// montuje se konektory k horní hraně.
part = "assembly";
/* [Filtr] */
filter_len = 104; // tělo vodorovně, bez konektorů
filter_h = 58; // svisle
filter_d = 45; // do hloubky vč. šroubů a rezervy
sma_len = 11; // jak daleko SMA trčí z čela
sma_z = 37; // osa SMA nad spodní hranou filtru (konektory nahoru)
sma_y = 18; // osa SMA od podstavy filtru
plug_clear = 22; // za koncem SMA: úhlový konektor kabelu
floor_clear = 10; // pod filtrem a nad ním
front_clear = 8; // mezi filtrem a víkem
standoff = 6; // sloupky pod filtrem
mount_dx = 95; // rozteč děr v rozích filtru, podélně
mount_dz = 51; // a napříč
post_d = 10; // sloupek kolem vložky
/* [Tvar] */
slant = 15; // sklon bočnic od svislice [°]
wall = 3;
flange = 12; // šířka příruby kolem otvoru (nese drážku i šrouby); 12 = ~238 mm, na MK4 ještě s brimem
flange_t = 5; // tloušťka příruby; slepá díra pro vložku pokračuje do náběhu pod ní
corner_r = 5; // poloměr vnitřních rohů; ven roste s offsetem (stěna 8, příruba 20),
// kulaté rohy se méně odlupují od podložky a náběh má i v rohu 45°
/* [Těsnění] */
groove_off = 1.5; // od vnitřní hrany příruby
groove_w = 2.5;
groove_d = 2.0;
gasket_h = 2.6; // ~30 % komprese
gasket_clr = 0.25; // vůle na každé straně drážky
/* [Šrouby M3 a zatavené vložky M3x5x5] */
insert_hole = 4.3; // pro vložku o vnějším průměru 5 mm
insert_depth = 5.6; // vložka 5 mm + místo na vytlačený plast
screw_hole = 3.4; // průchozí díra ve víku
screw_off = 7.5; // osa šroubů od vnitřní hrany příruby; vložka musí minout drážku
/* [Vývody] */
gland_hole = 18.6; // PG11 (závit 18,4 mm): SMA ~9,2 mm přes rohy
// projde s vyjmutou a podélně naříznutou vložkou; PG7 = 12.5, ale konektor neprojde
gland_dz = 0; // posun díry proti ose SMA (0 = v ose konektoru)
gland_teardrop = false; // true = slza bez supportu; kulatá díra líp sedí na závit vývodky
drain_hole = 4; // odtok kondenzátu v nejnižším bodě dna; 0 = bez
floor_slope = 4; // dno se ze všech stran svažuje k odtoku [°]
/* [Uchycení: stahovací pásky v zapuštěných tunelech] */
tie_w = 10; // šířka tunelu (pásek do 9 mm)
tie_gap = 2.5; // výška tunelu
tie_zs = [0.15, 0.5, 0.85]; // výšky tunelů jako podíl výšky krabice
tie_l = 60; // délka tunelu mezi vstupy (tyč do ~60 mm)
tie_skin = 3; // pod tunelem (strana k tyči)
tie_root = 2.5; // nad tunelem (strana do krabice) – nese tah pásku
lid_t = 3;
$fn = 48;
// ---- odvozené rozměry (vnitřek) ----
tn = tan(slant);
in_h = filter_h + 2 * floor_clear;
need_w = filter_len + 2 * (sma_len + plug_clear); // potřeba v úrovni spodní hrany filtru
in_wb = need_w - 2 * floor_clear * tn; // vnitřní šířka u dna
in_wt = in_wb + 2 * in_h * tn; // vnitřní šířka u stropu
in_d = standoff + filter_d + front_clear;
back_t = tie_skin + tie_gap + tie_root; // záda s tunely
depth = in_d + back_t;
in_y0 = -depth + back_t; // vnitřní plocha zad
filter_zc = floor_clear + filter_h / 2; // střed filtru (vnitřní z, dno = 0)
echo(str("vnitřek: dno ", in_wb, " / strop ", in_wt, " x výška ", in_h, " x hloubka ", in_d));
echo(str("obrys příruby: ", 2 * (corner_pt(2, -corner_r)[0] + corner_r + wall + flange), " x ", in_h + 2 * (wall + flange)));
echo(str("šrouby: vložka od drážky ", screw_off - groove_off - groove_w - insert_hole / 2,
", od okraje ", flange - screw_off - insert_hole / 2));
// Lichoběžník vnitřku posunutý o d ven (rovnoběžně se stěnami), dno vnitřku v z = 0.
function trap_pts(d) = let(
xb = in_wb / 2 - d * tn + d / cos(slant),
xt = in_wb / 2 + (in_h + d) * tn + d / cos(slant))
[[-xb, -d], [xb, -d], [xt, in_h + d], [-xt, in_h + d]];
module trap(d) { polygon(trap_pts(d)); }
// Vnitřek se zaoblenými rohy a jeho rovnoběžné offsety: stěna, drážka i příruba mají
// všude stejnou šířku a rohy se zaoblují s offsetem (ostrý offset dával v rohu převis ~56°).
module outline(d) { offset(r = corner_r + d) offset(delta = -corner_r) trap(0); }
// vrchol zaobleného rohu `outline(d)` u rohu i lichoběžníku
function unit(v) = v / norm(v);
function corner_pt(i, d) = let(
P = trap_pts(0), p = P[i],
u = unit(P[(i + 3) % 4] - p), v = unit(P[(i + 1) % 4] - p),
half = acos(u * v) / 2)
p + unit(u + v) * (corner_r / sin(half) - corner_r - d);
// 2D v rovině XZ vytažené v hloubce od y0 do y1
module xz(y0, y1) {
translate([0, y1, 0]) rotate([90, 0, 0]) linear_extrude(y1 - y0) children();
}
// šrouby v ose příruby: rohy + středy delších hran
function screw_pts() = let(
d = wall + screw_off,
p = trap_pts(d),
mid = function(a, b) (a + b) / 2)
concat([for (i = [0:3]) corner_pt(i, d)], [mid(p[0], p[1]), mid(p[2], p[3]),
mid(p[0], mid(p[0], p[1])), mid(p[1], mid(p[0], p[1])),
mid(p[2], mid(p[2], p[3])), mid(p[3], mid(p[2], p[3])),
mid(p[1], p[2]), mid(p[3], p[0])]);
module groove2d(clr = 0) {
difference() {
outline(wall + groove_off + groove_w - clr);
outline(wall + groove_off + clr);
}
}
sma_abs_z = floor_clear + sma_z; // osa SMA ve vnitřních z
module mount_post() {
// sloupek na zadní stěně; díra jen do sloupku, ne skrz stěnu
difference() {
rotate([-90, 0, 0]) cylinder(d = post_d, h = standoff);
translate([0, standoff - insert_depth, 0]) rotate([-90, 0, 0])
cylinder(d = insert_hole, h = insert_depth + 0.01);
}
}
module gland_cut(side) {
// kolmo na zkosenou bočnici => osa míří ven a dolů
z = sma_abs_z + gland_dz;
x = side * (in_wb / 2 + z * tn);
translate([x, in_y0 + standoff + sma_y, z])
rotate([0, side * (90 + slant), 0])
if (gland_teardrop) teardrop(gland_hole, 4 * wall);
else cylinder(d = gland_hole, h = 4 * wall, center = true);
}
// válec s převisem 45° ve špičce: osa podle z, špička míří k +y (při tisku nahoru)
module teardrop(d, h) {
linear_extrude(h, center = true)
hull() { circle(d = d); rotate(45) square(d / 2); }
}
// ---- dno jako trychtýř k odtoku ----
drain_y = in_y0 + in_d / 2;
funnel_h = 8;
module floor_funnel() {
difference() {
intersection() {
xz(in_y0, 0) outline(0);
translate([-in_wt, -depth, 0]) cube([2 * in_wt, depth, funnel_h]);
}
translate([0, drain_y, 0])
linear_extrude(height = funnel_h + 0.01, scale = 2 * funnel_h / tan(floor_slope) / 0.2)
square(0.2, center = true);
if (drain_hole > 0)
translate([0, drain_y, -1]) cylinder(d = drain_hole, h = funnel_h + 2);
}
}
// ---- tunely pro stahovací pásky ----
// Vedou vodorovně uvnitř zad, na zadní plochu vyúsťují šikmo pod 45°, takže
// pásek do tunelu sám zajede a vyjede druhým vstupem. Interiér neprotínají.
module tie_cut() {
y0 = -depth + tie_skin;
translate([-tie_l / 2, y0, -tie_w / 2]) cube([tie_l, tie_gap, tie_w]);
for (s = [-1, 1]) hull() {
translate([s * tie_l / 2 - 0.01, y0, -tie_w / 2]) cube([0.02, tie_gap, tie_w]);
translate([s * (tie_l / 2 + tie_skin) + (s > 0 ? 0 : -tie_gap), -depth - 1, -tie_w / 2])
cube([tie_gap, 1.01, tie_w]);
}
}
module body() {
difference() {
union() {
xz(-depth, 0) outline(wall);
xz(-flange_t, 0) outline(wall + flange);
// náběh 45° pod přírubou, aby se dala tisknout zády dolů bez supportu
hull() {
xz(-flange_t - flange, -flange_t - flange + 0.01) outline(wall);
xz(-flange_t - 0.01, -flange_t) outline(wall + flange);
}
}
xz(in_y0, 1) outline(0);
// drážka pro těsnění
translate([0, 0.01, 0]) xz(-groove_d, 0) groove2d();
// šrouby
for (p = screw_pts())
translate([p[0], 0.01, p[1]]) rotate([90, 0, 0]) cylinder(d = insert_hole, h = insert_depth);
for (s = [-1, 1]) gland_cut(s);
if (drain_hole > 0)
translate([0, drain_y, -wall - 1]) cylinder(d = drain_hole, h = wall + 2);
for (f = tie_zs) translate([0, 0, f * in_h]) tie_cut();
}
floor_funnel();
for (x = [-1, 1], z = [-1, 1])
translate([x * mount_dx / 2, in_y0, filter_zc + z * mount_dz / 2]) mount_post();
}
module lid() {
difference() {
xz(0, lid_t) outline(wall + flange);
for (p = screw_pts())
translate([p[0], lid_t + 1, p[1]]) rotate([90, 0, 0]) cylinder(d = screw_hole, h = lid_t + 2);
}
}
module gasket() { xz(-groove_d, -groove_d + gasket_h) groove2d(gasket_clr); }
module filter_dummy() {
color("silver")
translate([-filter_len / 2, in_y0 + standoff, floor_clear])
cube([filter_len, filter_d, filter_h]);
color("gold")
for (s = [-1, 1])
translate([s * filter_len / 2, in_y0 + standoff + sma_y, sma_abs_z])
rotate([0, s * 90, 0]) cylinder(d = 6.4, h = sma_len);
}
// tisk: tělo zády dolů, víko těsnicí plochou dolů, těsnění z TPU naplocho
if (part == "body") translate([0, 0, depth]) rotate([90, 0, 0]) body();
else if (part == "lid") rotate([90, 0, 0]) lid();
else if (part == "gasket") rotate([-90, 0, 0]) translate([0, groove_d, 0]) gasket();
else {
color("orange", 0.85) body();
color("black") gasket();
filter_dummy();
if (part == "assembly") color("lightblue", 0.35) translate([0, 25, 0]) lid();
}